1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Int 13h function AH=24h, Set Multiple Blocks. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; Int 13h function AH=24h, Set Multiple Blocks. |
---|
25 | ; |
---|
26 | ; AH24h_HandlerForSetMultipleBlocks |
---|
27 | ; Parameters: |
---|
28 | ; AL: Same as in INTPACK |
---|
29 | ; DL: Translated Drive number |
---|
30 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
31 | ; SS:BP: Ptr to IDEPACK |
---|
32 | ; Parameters on INTPACK: |
---|
33 | ; AL: Number of Sectors per Block (1, 2, 4, 8, 16, 32, 64 or 128) |
---|
34 | ; Returns with INTPACK: |
---|
35 | ; AH: Int 13h return status |
---|
36 | ; CF: 0 if successful, 1 if error |
---|
37 | ;-------------------------------------------------------------------- |
---|
38 | AH24h_HandlerForSetMultipleBlocks: |
---|
39 | %ifndef USE_186 |
---|
40 | call AH24h_SetBlockSize |
---|
41 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|
42 | %else |
---|
43 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|
44 | ; Fall to AH24h_SetBlockSize |
---|
45 | %endif |
---|
46 | |
---|
47 | |
---|
48 | ;-------------------------------------------------------------------- |
---|
49 | ; AH24h_SetBlockSize |
---|
50 | ; Parameters: |
---|
51 | ; AL: Number of Sectors per Block (1, 2, 4, 8, 16, 32, 64 or 128) |
---|
52 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
53 | ; SS:BP: Ptr to IDEPACK |
---|
54 | ; Returns: |
---|
55 | ; AH: Int 13h return status |
---|
56 | ; CF: 0 if successful, 1 if error |
---|
57 | ; Corrupts registers: |
---|
58 | ; AL, CX, DX |
---|
59 | ;-------------------------------------------------------------------- |
---|
60 | AH24h_SetBlockSize: |
---|
61 | %ifdef MODULE_8BIT_IDE_ADVANCED |
---|
62 | ; XT-CF does not support largest block size in DMA mode. |
---|
63 | cmp al, XTCF_DMA_MODE_MAX_BLOCK_SIZE |
---|
64 | jbe SHORT .NoNeedToLimitBlockSize |
---|
65 | |
---|
66 | ; Return error if we tried too large block for XT-CF. |
---|
67 | ; Do not limit it to maximum supported since software calling AH=24h |
---|
68 | ; must know what the actual block size is. |
---|
69 | cmp BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_XTCF_DMA |
---|
70 | je SHORT ProcessXTCFsubcommandFromAL.AH1Eh_LoadInvalidCommandToAHandSetCF |
---|
71 | .NoNeedToLimitBlockSize: |
---|
72 | %endif ; MODULE_8BIT_IDE_ADVANCED |
---|
73 | |
---|
74 | push bx |
---|
75 | |
---|
76 | push ax ; Store block size for later use |
---|
77 | xchg dx, ax ; DL = Block size (Sector Count Register) |
---|
78 | mov al, COMMAND_SET_MULTIPLE_MODE |
---|
79 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRDY, FLG_STATUS_DRDY) |
---|
80 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL |
---|
81 | |
---|
82 | ; Disable block mode if failure or if called with block size of 1 sector. |
---|
83 | ; Some drives allow block mode commands for 1 sector blocks and some do not. |
---|
84 | pop bx ; Pop block size to BL |
---|
85 | jc SHORT .DisableBlockMode |
---|
86 | |
---|
87 | ; All valid block sizes are powers of 2 which means BL have just one bit set (parity odd). |
---|
88 | ; Incrementing BX will cause all block sizes except 1 to have two bits set (parity even). |
---|
89 | ; Note that PF reflects only the lowest 8 bits of any register being modified. |
---|
90 | inc bx ; 1 -> 2 ? |
---|
91 | jpo SHORT .DisableBlockMode ; Jump if BL = 2 |
---|
92 | dec bx ; Restore block size (was larger than 1) |
---|
93 | |
---|
94 | ; Enable block mode and store block size |
---|
95 | or BYTE [di+DPT.bFlagsHigh], FLGH_DPT_USE_BLOCK_MODE_COMMANDS |
---|
96 | jmp SHORT .StoreBlockSizeFromBLandReturn |
---|
97 | |
---|
98 | .DisableBlockMode: |
---|
99 | and BYTE [di+DPT.bFlagsHigh], ~FLGH_DPT_USE_BLOCK_MODE_COMMANDS |
---|
100 | mov bl, 1 |
---|
101 | stc |
---|
102 | .StoreBlockSizeFromBLandReturn: |
---|
103 | mov [di+DPT_ATA.bBlockSize], bl |
---|
104 | pop bx |
---|
105 | ret |
---|