1 | ; Project name : Assembly Library |
---|
2 | ; Description : Functions for outputting characters to video memory. |
---|
3 | ; These functions are meant to be called by Display_CharacterFromAL |
---|
4 | ; and Display_RepeatCharacterFromAL using function pointer |
---|
5 | ; stored in DISPLAY_CONTEXT. |
---|
6 | |
---|
7 | ; |
---|
8 | ; XTIDE Universal BIOS and Associated Tools |
---|
9 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
10 | ; |
---|
11 | ; This program is free software; you can redistribute it and/or modify |
---|
12 | ; it under the terms of the GNU General Public License as published by |
---|
13 | ; the Free Software Foundation; either version 2 of the License, or |
---|
14 | ; (at your option) any later version. |
---|
15 | ; |
---|
16 | ; This program is distributed in the hope that it will be useful, |
---|
17 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
18 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
19 | ; GNU General Public License for more details. |
---|
20 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
21 | ; |
---|
22 | |
---|
23 | ; Section containing code |
---|
24 | SECTION .text |
---|
25 | |
---|
26 | ;-------------------------------------------------------------------- |
---|
27 | ; DisplayCharOut_TeletypeOutputWithAttribute |
---|
28 | ; DisplayCharOut_TeletypeOutput |
---|
29 | ; Parameters: |
---|
30 | ; AL: Character to output |
---|
31 | ; AH: Attribute to output |
---|
32 | ; DS: BDA segment (zero) |
---|
33 | ; ES:DI: Ptr to video memory where to output |
---|
34 | ; Returns: |
---|
35 | ; DI: Incremented for next character |
---|
36 | ; Corrupts registers: |
---|
37 | ; AX, DX |
---|
38 | ;-------------------------------------------------------------------- |
---|
39 | ALIGN DISPLAY_JUMP_ALIGN |
---|
40 | DisplayCharOut_TeletypeOutputWithAttribute: |
---|
41 | cmp al, ' ' ; Printable character? |
---|
42 | jb SHORT DisplayCharOut_BiosTeletypeOutput |
---|
43 | JMP_WAIT_FOR_RETRACE_IF_NECESSARY_THEN stosw |
---|
44 | |
---|
45 | ALIGN DISPLAY_JUMP_ALIGN |
---|
46 | DisplayCharOut_TeletypeOutput: |
---|
47 | cmp al, ' ' ; Printable character? |
---|
48 | jae SHORT DisplayCharOut_Character |
---|
49 | ; Fall to DisplayCharOut_BiosTeletypeOutput |
---|
50 | |
---|
51 | ;-------------------------------------------------------------------- |
---|
52 | ; DisplayCharOut_BiosTeletypeOutput |
---|
53 | ; Parameters: |
---|
54 | ; AL: Control character |
---|
55 | ; DS: BDA segment (zero) |
---|
56 | ; ES:DI: Ptr to video memory where to output |
---|
57 | ; Returns: |
---|
58 | ; DI: Incremented for next character |
---|
59 | ; Corrupts registers: |
---|
60 | ; AX, DX |
---|
61 | ;-------------------------------------------------------------------- |
---|
62 | ALIGN DISPLAY_JUMP_ALIGN |
---|
63 | DisplayCharOut_BiosTeletypeOutput: |
---|
64 | push ax |
---|
65 | call DisplayCursor_SynchronizeCoordinatesToHardware |
---|
66 | pop ax |
---|
67 | |
---|
68 | ; Output character with BIOS |
---|
69 | push bx |
---|
70 | mov ah, TELETYPE_OUTPUT |
---|
71 | mov bh, [VIDEO_BDA.bActivePage] |
---|
72 | int BIOS_VIDEO_INTERRUPT_10h |
---|
73 | pop bx |
---|
74 | |
---|
75 | call DisplayCursor_GetHardwareCoordinatesToAX |
---|
76 | jmp DisplayCursor_SetCoordinatesFromAX |
---|
77 | |
---|
78 | |
---|
79 | ;-------------------------------------------------------------------- |
---|
80 | ; DisplayCharOut_Attribute |
---|
81 | ; DisplayCharOut_Character |
---|
82 | ; DisplayCharOut_CharacterWithAttribute |
---|
83 | ; Parameters: |
---|
84 | ; AL: Character to output |
---|
85 | ; AH: Attribute to output |
---|
86 | ; DS: BDA segment (zero) |
---|
87 | ; ES:DI: Ptr to video memory where to output |
---|
88 | ; Returns: |
---|
89 | ; DI: Incremented for next character |
---|
90 | ; Corrupts registers: |
---|
91 | ; AX, DX |
---|
92 | ;-------------------------------------------------------------------- |
---|
93 | ALIGN DISPLAY_JUMP_ALIGN |
---|
94 | DisplayCharOut_Attribute: |
---|
95 | xchg al, ah ; Swap character and attribute |
---|
96 | inc di ; Skip character |
---|
97 | JMP_WAIT_FOR_RETRACE_IF_NECESSARY_THEN stosb |
---|
98 | |
---|
99 | ALIGN DISPLAY_JUMP_ALIGN |
---|
100 | DisplayCharOut_Character: |
---|
101 | CALL_WAIT_FOR_RETRACE_IF_NECESSARY_THEN stosb |
---|
102 | inc di ; Skip attribute |
---|
103 | ret |
---|
104 | |
---|
105 | ALIGN DISPLAY_JUMP_ALIGN |
---|
106 | DisplayCharOut_CharacterWithAttribute: |
---|
107 | JMP_WAIT_FOR_RETRACE_IF_NECESSARY_THEN stosw |
---|
108 | |
---|
109 | |
---|
110 | ;-------------------------------------------------------------------- |
---|
111 | ; DisplayCharOut_WriteCharacterToBuffer |
---|
112 | ; Parameters: |
---|
113 | ; AL: Character to output |
---|
114 | ; DS: BDA segment (zero) |
---|
115 | ; ES:DI: Ptr to destination string buffer |
---|
116 | ; DISPLAY_CONTEXT.wCharOutParam: Characters left in buffer |
---|
117 | ; Returns: |
---|
118 | ; ES:DI: Updated for next character |
---|
119 | ; Corrupts registers: |
---|
120 | ; AX, DX |
---|
121 | ;-------------------------------------------------------------------- |
---|
122 | ALIGN DISPLAY_JUMP_ALIGN |
---|
123 | DisplayCharOut_WriteCharacterToBuffer: |
---|
124 | cmp WORD [VIDEO_BDA.displayContext+DISPLAY_CONTEXT.wCharOutParam], BYTE 0 |
---|
125 | je SHORT .BufferFull |
---|
126 | stosb |
---|
127 | dec WORD [VIDEO_BDA.displayContext+DISPLAY_CONTEXT.wCharOutParam] |
---|
128 | .BufferFull: |
---|
129 | ret |
---|