| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Functions for creating Disk Parameter Table.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; Creates new Disk Parameter Table for detected hard disk.
|
|---|
| 25 | ; Drive is then fully accessible using any BIOS function.
|
|---|
| 26 | ;
|
|---|
| 27 | ; CreateDPT_FromAtaInformation
|
|---|
| 28 | ; Parameters:
|
|---|
| 29 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 30 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 31 | ; ES:SI: Ptr to 512-byte ATA information read from the drive
|
|---|
| 32 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 33 | ; DS: RAMVARS segment
|
|---|
| 34 | ; ES: BDA Segment
|
|---|
| 35 | ; Returns:
|
|---|
| 36 | ; DS:DI: Ptr to Disk Parameter Table (if successful)
|
|---|
| 37 | ; CF: Cleared if DPT created successfully
|
|---|
| 38 | ; Set if any error
|
|---|
| 39 | ; Corrupts registers:
|
|---|
| 40 | ; AX, BX, CX, DX
|
|---|
| 41 | ;--------------------------------------------------------------------
|
|---|
| 42 | CreateDPT_FromAtaInformation:
|
|---|
| 43 | call FindDPT_ForNewDriveToDSDI
|
|---|
| 44 | ; Fall to .InitializeDPT
|
|---|
| 45 |
|
|---|
| 46 | ;--------------------------------------------------------------------
|
|---|
| 47 | ; .InitializeDPT
|
|---|
| 48 | ; Parameters:
|
|---|
| 49 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 50 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 51 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 52 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 53 | ; Returns:
|
|---|
| 54 | ; Nothing
|
|---|
| 55 | ; Corrupts registers:
|
|---|
| 56 | ; AX
|
|---|
| 57 | ;--------------------------------------------------------------------
|
|---|
| 58 | .InitializeDPT:
|
|---|
| 59 | call CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI
|
|---|
| 60 | ; Fall to .StoreDriveSelectAndDriveControlByte
|
|---|
| 61 |
|
|---|
| 62 | ;--------------------------------------------------------------------
|
|---|
| 63 | ; .StoreDriveSelectAndDriveControlByte
|
|---|
| 64 | ; Parameters:
|
|---|
| 65 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 66 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 67 | ; ES:SI: Ptr to 512-byte ATA information read from the drive
|
|---|
| 68 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 69 | ; Returns:
|
|---|
| 70 | ; Nothing
|
|---|
| 71 | ; Corrupts registers:
|
|---|
| 72 | ; AX
|
|---|
| 73 | ;--------------------------------------------------------------------
|
|---|
| 74 | .StoreDriveSelectAndDriveControlByte:
|
|---|
| 75 | mov al, bh
|
|---|
| 76 | and ax, BYTE FLG_DRVNHEAD_DRV ; AL now has Master/Slave bit
|
|---|
| 77 | %ifdef MODULE_IRQ
|
|---|
| 78 | cmp [cs:bp+IDEVARS.bIRQ], ah ; Interrupts enabled?
|
|---|
| 79 | jz SHORT .StoreFlags ; If not, do not set interrupt flag
|
|---|
| 80 | or al, FLGL_DPT_ENABLE_IRQ
|
|---|
| 81 | .StoreFlags:
|
|---|
| 82 | %endif
|
|---|
| 83 | mov [di+DPT.wFlags], ax
|
|---|
| 84 | ; Fall to .StoreCHSparametersAndAddressingMode
|
|---|
| 85 |
|
|---|
| 86 | ;--------------------------------------------------------------------
|
|---|
| 87 | ; .StoreCHSparametersAndAddressingMode
|
|---|
| 88 | ; Parameters:
|
|---|
| 89 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 90 | ; ES:SI: Ptr to 512-byte ATA information read from the drive
|
|---|
| 91 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 92 | ; Returns:
|
|---|
| 93 | ; Nothing
|
|---|
| 94 | ; Corrupts registers:
|
|---|
| 95 | ; AX, BX, CX, DX
|
|---|
| 96 | ;--------------------------------------------------------------------
|
|---|
| 97 | .StoreCHSparametersAndAddressingMode:
|
|---|
| 98 | ; Apply any user limited values to ATA ID
|
|---|
| 99 | call AtaID_ModifyESSIforUserDefinedLimitsAndReturnTranslateModeInDX
|
|---|
| 100 |
|
|---|
| 101 | ; Translate P-CHS to L-CHS
|
|---|
| 102 | call AtaGeometry_GetLCHStoAXBLBHfromAtaInfoInESSIwithTranslateModeInDX
|
|---|
| 103 | mov [di+DPT.wLchsCylinders], ax
|
|---|
| 104 | mov [di+DPT.wLchsHeadsAndSectors], bx
|
|---|
| 105 | mov al, dl
|
|---|
| 106 | eSHL_IM al, TRANSLATEMODE_FIELD_POSITION
|
|---|
| 107 | or cl, al
|
|---|
| 108 |
|
|---|
| 109 | ; Store P-CHS and flags
|
|---|
| 110 | call AtaGeometry_GetPCHStoAXBLBHfromAtaInfoInESSI
|
|---|
| 111 | dec dl ; Set ZF if TRANSLATEMODE_LARGE, SF if TRANSLATEMODE_NORMAL
|
|---|
| 112 | js SHORT .NothingToChange
|
|---|
| 113 | jz SHORT .LimitHeadsForLargeAddressingMode
|
|---|
| 114 |
|
|---|
| 115 | ; Set LBA bit for Assisted LBA
|
|---|
| 116 | or cl, FLGL_DPT_LBA
|
|---|
| 117 | jmp SHORT .NothingToChange
|
|---|
| 118 |
|
|---|
| 119 | .LimitHeadsForLargeAddressingMode:
|
|---|
| 120 | ; We cannot have 16 P-Heads heads in Revised ECHS mode (8193 or more cylinders)
|
|---|
| 121 | ; but 16 heads are allowed when there are 8192 or less cylinders (ECHS).
|
|---|
| 122 | ; Both of these are LARGE modes so do not confuse with NORMAL mode.
|
|---|
| 123 | call AtaGeometry_IsDriveSmallEnoughForECHS
|
|---|
| 124 | jc SHORT .NothingToChange
|
|---|
| 125 | dec bx ; Adjust 16 P-Heads to 15
|
|---|
| 126 |
|
|---|
| 127 | .NothingToChange:
|
|---|
| 128 | or [di+DPT.bFlagsLow], cl ; Shift count and addressing mode
|
|---|
| 129 | mov [di+DPT.wPchsHeadsAndSectors], bx
|
|---|
| 130 |
|
|---|
| 131 | %ifdef MODULE_EBIOS
|
|---|
| 132 | ; Store P-Cylinders here for Compatible DPTs when FLGL_DPT_LBA is not set
|
|---|
| 133 | ; or when drive has over 15,482,880 sectors
|
|---|
| 134 | mov [di+DPT.wPchsCylinders], ax
|
|---|
| 135 | test cl, FLGL_DPT_LBA
|
|---|
| 136 | jz SHORT .NoLbaSoNoEBIOS
|
|---|
| 137 |
|
|---|
| 138 | ; Store P-Cylinders but only if we have 15,482,880 or less sectors since
|
|---|
| 139 | ; we only need P-Cylinders so we can return it from AH=48h
|
|---|
| 140 | call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI
|
|---|
| 141 | sub ax, (MAX_SECTOR_COUNT_TO_RETURN_PCHS+1) & 0FFFFh
|
|---|
| 142 | sbb dx, (MAX_SECTOR_COUNT_TO_RETURN_PCHS+1) >> 16
|
|---|
| 143 | sbb bx, BYTE 0
|
|---|
| 144 | jnc SHORT .StoreNumberOfLbaSectors
|
|---|
| 145 |
|
|---|
| 146 | ; Since we might have altered the default P-CHS parameters to be
|
|---|
| 147 | ; presented to the drive (AH=09h), we need to calculate new
|
|---|
| 148 | ; P-Cylinders. It could be read from the ATA ID after
|
|---|
| 149 | ; COMMAND_INITIALIZE_DEVICE_PARAMETERS but that is too much trouble.
|
|---|
| 150 | ; P-Cyls = MIN(16383*16*63, LBA sector count) / (P-Heads * P-Sectors per track)
|
|---|
| 151 | call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI
|
|---|
| 152 | xchg cx, ax ; Sector count to DX:CX
|
|---|
| 153 | mov al, [di+DPT.bPchsHeads]
|
|---|
| 154 | mul BYTE [di+DPT.bPchsSectorsPerTrack]
|
|---|
| 155 | xchg cx, ax
|
|---|
| 156 | div cx ; AX = new P-Cylinders
|
|---|
| 157 |
|
|---|
| 158 | ; We could remove wPchsCylinders from DPT if we calculate it on AH=48h
|
|---|
| 159 | ; (and for compatible DPTs) but that would require extra code so we save ROM space instead.
|
|---|
| 160 | mov [di+DPT.wPchsCylinders], ax
|
|---|
| 161 |
|
|---|
| 162 | ; Store CHS sector count as total sector count. We must not use
|
|---|
| 163 | ; LBA sector count if it is 15,482,880 or less.
|
|---|
| 164 | mul cx
|
|---|
| 165 | xor bx, bx
|
|---|
| 166 | jmp SHORT .StoreTotalSectorsFromBXDXAX
|
|---|
| 167 | ; Fall to .StoreNumberOfLbaSectors
|
|---|
| 168 |
|
|---|
| 169 | ;--------------------------------------------------------------------
|
|---|
| 170 | ; .StoreNumberOfLbaSectors
|
|---|
| 171 | ; Parameters:
|
|---|
| 172 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 173 | ; ES:SI: Ptr to 512-byte ATA information read from the drive
|
|---|
| 174 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 175 | ; Returns:
|
|---|
| 176 | ; Nothing
|
|---|
| 177 | ; Corrupts registers:
|
|---|
| 178 | ; AX, BX, CX, DX
|
|---|
| 179 | ;--------------------------------------------------------------------
|
|---|
| 180 | .StoreNumberOfLbaSectors:
|
|---|
| 181 | ; Store LBA 28/48 total sector count
|
|---|
| 182 | call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI
|
|---|
| 183 | or [di+DPT.bFlagsLow], cl ; LBA48 flag
|
|---|
| 184 | .StoreTotalSectorsFromBXDXAX:
|
|---|
| 185 | mov [di+DPT.twLbaSectors], ax
|
|---|
| 186 | mov [di+DPT.twLbaSectors+2], dx
|
|---|
| 187 | mov [di+DPT.twLbaSectors+4], bx
|
|---|
| 188 | .NoLbaSoNoEBIOS:
|
|---|
| 189 | %endif ; MODULE_EBIOS
|
|---|
| 190 | ; Fall to .StoreBlockMode
|
|---|
| 191 |
|
|---|
| 192 | ;--------------------------------------------------------------------
|
|---|
| 193 | ; .StoreBlockMode
|
|---|
| 194 | ; Parameters:
|
|---|
| 195 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 196 | ; ES:SI: Ptr to 512-byte ATA information read from the drive
|
|---|
| 197 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 198 | ; Returns:
|
|---|
| 199 | ; Nothing
|
|---|
| 200 | ; Corrupts registers:
|
|---|
| 201 | ; Nothing
|
|---|
| 202 | ;--------------------------------------------------------------------
|
|---|
| 203 | .StoreBlockMode:
|
|---|
| 204 | cmp BYTE [es:si+ATA1.bBlckSize], 1 ; Max block size in sectors
|
|---|
| 205 | jbe SHORT .BlockModeTransfersNotSupported
|
|---|
| 206 | or BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
|
|---|
| 207 | .BlockModeTransfersNotSupported:
|
|---|
| 208 | ; Fall to .StoreDeviceSpecificParameters
|
|---|
| 209 |
|
|---|
| 210 | ;--------------------------------------------------------------------
|
|---|
| 211 | ; .StoreDeviceSpecificParameters
|
|---|
| 212 | ; Parameters:
|
|---|
| 213 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 214 | ; ES:SI: Ptr to 512-byte ATA information read from the drive
|
|---|
| 215 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 216 | ; Returns:
|
|---|
| 217 | ; Nothing
|
|---|
| 218 | ; Corrupts registers:
|
|---|
| 219 | ; AX, BX, CX, DX
|
|---|
| 220 | ;--------------------------------------------------------------------
|
|---|
| 221 | .StoreDeviceSpecificParameters:
|
|---|
| 222 | call Device_FinalizeDPT
|
|---|
| 223 |
|
|---|
| 224 | ;----------------------------------------------------------------------
|
|---|
| 225 | ; Update drive counts (hard and floppy)
|
|---|
| 226 | ;----------------------------------------------------------------------
|
|---|
| 227 |
|
|---|
| 228 | %ifdef MODULE_SERIAL_FLOPPY
|
|---|
| 229 | ;
|
|---|
| 230 | ; These two instructions serve two purposes:
|
|---|
| 231 | ; 1. If the drive is a floppy drive (CF set), then we effectively increment the counter.
|
|---|
| 232 | ; 2. If this is a hard disk, and there have been any floppy drives previously added, then the hard disk is
|
|---|
| 233 | ; effectively discarded. This is more of a safety check then code that should ever normally be hit (see below).
|
|---|
| 234 | ; Since the floppy DPT's come after the hard disk DPT's, without expensive (code size) code to relocate a DPT,
|
|---|
| 235 | ; this was necessary. Now, this situation shouldn't happen in normal operation, for a couple of reasons:
|
|---|
| 236 | ; A. xtidecfg always puts configured serial ports at the end of the IDEVARS list
|
|---|
| 237 | ; B. the auto serial code is always executed last
|
|---|
| 238 | ; C. the serial server always returns floppy drives last
|
|---|
| 239 | ;
|
|---|
| 240 | adc byte [RAMVARS.xlateVars+XLATEVARS.bFlopCreateCnt], 0
|
|---|
| 241 | jnz .AllDone
|
|---|
| 242 | %else
|
|---|
| 243 | ;
|
|---|
| 244 | ; Even without floppy support enabled, we shouldn't try to mount a floppy image as a hard disk, which
|
|---|
| 245 | ; could lead to unpredictable results since no MBR will be present, etc. The server doesn't know that
|
|---|
| 246 | ; floppies are supported, so it is important to still fail here if a floppy is seen during the drive scan.
|
|---|
| 247 | ;
|
|---|
| 248 | jc .AllDone
|
|---|
| 249 | %endif
|
|---|
| 250 |
|
|---|
| 251 | inc BYTE [RAMVARS.bDrvCnt] ; Increment drive count to RAMVARS
|
|---|
| 252 |
|
|---|
| 253 | .AllDone:
|
|---|
| 254 | clc
|
|---|
| 255 | ret
|
|---|
| 256 |
|
|---|
| 257 |
|
|---|
| 258 | ;--------------------------------------------------------------------
|
|---|
| 259 | ; CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI
|
|---|
| 260 | ; Parameters:
|
|---|
| 261 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 262 | ; DS:DI: Ptr to Disk Parameter Table
|
|---|
| 263 | ; CS:BP: Ptr to IDEVARS for the controller
|
|---|
| 264 | ; Returns:
|
|---|
| 265 | ; Nothing
|
|---|
| 266 | ; Corrupts registers:
|
|---|
| 267 | ; AX
|
|---|
| 268 | ;--------------------------------------------------------------------
|
|---|
| 269 | CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI:
|
|---|
| 270 | mov [di+DPT.bIdevarsOffset], bp ; IDEVARS must start in first 256 bytes of ROM
|
|---|
| 271 | mov ax, [cs:bp+IDEVARS.wBasePort]
|
|---|
| 272 | mov [di+DPT.wBasePort], ax
|
|---|
| 273 | ret
|
|---|
