Context Navigation

source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/VariablesAndDPTs/CreateDPT.asm@ 542

Visit:

Last change on this file since 542 was 542, checked in by aitotat@…, 12 years ago

Changes to XTIDE Universal BIOS:

Fixed a bug that allowed EBIOS functions for user defined CHS.
Simplified user defined CHS and LBA setup a little.

File size: 9.8 KB

Rev	Line
[99]	1	; Project name : XTIDE Universal BIOS
[3]	2	; Description : Functions for creating Disk Parameter Table.
	3
[376]	4	;
[445]	5	; XTIDE Universal BIOS and Associated Tools
[526]	6	; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
[376]	7	;
	8	; This program is free software; you can redistribute it and/or modify
	9	; it under the terms of the GNU General Public License as published by
	10	; the Free Software Foundation; either version 2 of the License, or
	11	; (at your option) any later version.
[445]	12	;
[376]	13	; This program is distributed in the hope that it will be useful,
	14	; but WITHOUT ANY WARRANTY; without even the implied warranty of
	15	; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
[445]	16	; GNU General Public License for more details.
[376]	17	; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
[445]	18	;
[376]	19
[3]	20	; Section containing code
	21	SECTION .text
	22
	23	;--------------------------------------------------------------------
	24	; Creates new Disk Parameter Table for detected hard disk.
	25	; Drive is then fully accessible using any BIOS function.
	26	;
	27	; CreateDPT_FromAtaInformation
	28	; Parameters:
	29	; BH: Drive Select byte for Drive and Head Register
[473]	30	; DX: Autodetected port (for devices that support autodetection)
[3]	31	; ES:SI: Ptr to 512-byte ATA information read from the drive
	32	; CS:BP: Ptr to IDEVARS for the controller
	33	; DS: RAMVARS segment
	34	; ES: BDA Segment
	35	; Returns:
[294]	36	; DS:DI: Ptr to Disk Parameter Table (if successful)
[3]	37	; CF: Cleared if DPT created successfully
	38	; Set if any error
	39	; Corrupts registers:
[542]	40	; AX, BX, CX, DX
[3]	41	;--------------------------------------------------------------------
	42	CreateDPT_FromAtaInformation:
[150]	43	call FindDPT_ForNewDriveToDSDI
[99]	44	; Fall to .InitializeDPT
[3]	45
	46	;--------------------------------------------------------------------
[99]	47	; .InitializeDPT
[3]	48	; Parameters:
	49	; BH: Drive Select byte for Drive and Head Register
[473]	50	; DX: Autodetected port (for devices that support autodetection)
[3]	51	; DS:DI: Ptr to Disk Parameter Table
	52	; CS:BP: Ptr to IDEVARS for the controller
	53	; Returns:
[150]	54	; Nothing
[3]	55	; Corrupts registers:
[150]	56	; AX
[3]	57	;--------------------------------------------------------------------
[99]	58	.InitializeDPT:
[473]	59	call CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI
[150]	60	; Fall to .StoreDriveSelectAndDriveControlByte
[3]	61
	62	;--------------------------------------------------------------------
[150]	63	; .StoreDriveSelectAndDriveControlByte
[3]	64	; Parameters:
	65	; BH: Drive Select byte for Drive and Head Register
	66	; DS:DI: Ptr to Disk Parameter Table
	67	; ES:SI: Ptr to 512-byte ATA information read from the drive
	68	; CS:BP: Ptr to IDEVARS for the controller
	69	; Returns:
[99]	70	; Nothing
[3]	71	; Corrupts registers:
	72	; AX
	73	;--------------------------------------------------------------------
[150]	74	.StoreDriveSelectAndDriveControlByte:
	75	mov al, bh
	76	and ax, BYTE FLG_DRVNHEAD_DRV ; AL now has Master/Slave bit
[411]	77	%ifdef MODULE_IRQ
[150]	78	cmp [cs:bp+IDEVARS.bIRQ], ah ; Interrupts enabled?
	79	jz SHORT .StoreFlags ; If not, do not set interrupt flag
[158]	80	or al, FLGL_DPT_ENABLE_IRQ
[150]	81	.StoreFlags:
[411]	82	%endif
[150]	83	mov [di+DPT.wFlags], ax
[421]	84	; Fall to .StoreCHSparametersAndAddressingMode
[3]	85
	86	;--------------------------------------------------------------------
[421]	87	; .StoreCHSparametersAndAddressingMode
[3]	88	; Parameters:
	89	; DS:DI: Ptr to Disk Parameter Table
	90	; ES:SI: Ptr to 512-byte ATA information read from the drive
	91	; CS:BP: Ptr to IDEVARS for the controller
	92	; Returns:
[227]	93	; Nothing
[3]	94	; Corrupts registers:
[227]	95	; AX, BX, CX, DX
[3]	96	;--------------------------------------------------------------------
[421]	97	.StoreCHSparametersAndAddressingMode:
[542]	98	; Apply any user limited values to ATA ID
	99	call AtaID_ModifyESSIforUserDefinedLimitsAndReturnTranslateModeInDX
[173]	100
[422]	101	; Translate P-CHS to L-CHS
	102	call AtaGeometry_GetLCHStoAXBLBHfromAtaInfoInESSIandTranslateModeInDX
[421]	103	mov [di+DPT.wLchsCylinders], ax
	104	mov [di+DPT.wLchsHeadsAndSectors], bx
[542]	105	mov al, dl
	106	eSHL_IM al, TRANSLATEMODE_FIELD_POSITION
	107	or cl, al
[421]	108
[542]	109	; Store P-CHS and flags
[421]	110	call AtaGeometry_GetPCHStoAXBLBHfromAtaInfoInESSI
[542]	111	dec dx ; Set ZF if TRANSLATEMODE_LARGE, SF if TRANSLATEMODE_NORMAL
	112	js SHORT .NothingToChange
	113	jz SHORT .LimitHeadsForLargeAddressingMode
	114
	115	or cl, FLGL_DPT_LBA ; Set LBA bit for Assisted LBA
	116	jmp SHORT .NothingToChange
	117	.LimitHeadsForLargeAddressingMode:
	118	MIN_U bl, 15 ; Cannot have 16 P-Heads in LARGE addressing mode
	119	.NothingToChange:
	120	or [di+DPT.bFlagsLow], cl ; Shift count and addressing mode
	121	mov [di+DPT.wPchsHeadsAndSectors], bx
	122
[421]	123	%ifdef MODULE_EBIOS
[542]	124	test cl, FLGL_DPT_LBA
	125	jz SHORT .NoLbaSoNoEBIOS
[533]	126
[542]	127	; Store P-Cylinders but only if we have 15,482,880 or less sectors since
	128	; we only need P-Cylinders so we can return it from AH=48h
	129	call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI
	130	sub ax, MAX_SECTOR_COUNT_TO_RETURN_PCHS & 0FFFFh
	131	sbb dx, MAX_SECTOR_COUNT_TO_RETURN_PCHS >> 16
	132	sbb bx, BYTE 0
	133	ja SHORT .StoreNumberOfLbaSectors
[533]	134
[542]	135	; Since we might have altered the default P-CHS parameters to be
	136	; presented to the drive (AH=09h), we need to calculate new
	137	; P-Cylinders. It could be read from the ATA ID after
	138	; COMMAND_INITIALIZE_DEVICE_PARAMETERS but that is too much trouble.
	139	; P-Cyls = MIN(163831663, LBA sector count) / (P-Heads * P-Sectors per track)
	140	call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI
	141	xchg cx, ax ; Sector count to DX:CX
	142	mov al, [di+DPT.bPchsHeads]
	143	mul BYTE [di+DPT.bPchsSectorsPerTrack]
	144	xchg cx, ax
	145	div cx ; AX = new P-Cylinders
[421]	146	mov [di+DPT.wPchsCylinders], ax
[542]	147
	148	; Store CHS sector count as total sector count
	149	mul cx
	150	xor bx, bx
	151	xor cx, cx ; Clear LBA48 flag
	152	jmp SHORT .StoreTotalSectorsFromBXDXAXandLBA48flagFromCL
[421]	153	; Fall to .StoreNumberOfLbaSectors
	154
	155	;--------------------------------------------------------------------
	156	; .StoreNumberOfLbaSectors
	157	; Parameters:
	158	; DS:DI: Ptr to Disk Parameter Table
	159	; ES:SI: Ptr to 512-byte ATA information read from the drive
	160	; CS:BP: Ptr to IDEVARS for the controller
	161	; Returns:
	162	; Nothing
	163	; Corrupts registers:
	164	; AX, BX, CX, DX
	165	;--------------------------------------------------------------------
[542]	166	.StoreNumberOfLbaSectors:
[421]	167	; Store LBA 28/48 total sector count
	168	call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI
[542]	169	.StoreTotalSectorsFromBXDXAXandLBA48flagFromCL:
	170	or [di+DPT.bFlagsLow], cl
	171	mov [di+DPT.twLbaSectors], ax
	172	mov [di+DPT.twLbaSectors+2], dx
	173	mov [di+DPT.twLbaSectors+4], bx
	174	.NoLbaSoNoEBIOS:
[421]	175	%endif ; MODULE_EBIOS
[99]	176	; Fall to .StoreBlockMode
[3]	177
	178	;--------------------------------------------------------------------
[99]	179	; .StoreBlockMode
[3]	180	; Parameters:
	181	; DS:DI: Ptr to Disk Parameter Table
	182	; ES:SI: Ptr to 512-byte ATA information read from the drive
[160]	183	; CS:BP: Ptr to IDEVARS for the controller
[3]	184	; Returns:
[99]	185	; Nothing
[3]	186	; Corrupts registers:
[150]	187	; Nothing
[3]	188	;--------------------------------------------------------------------
[99]	189	.StoreBlockMode:
[150]	190	cmp BYTE [es:si+ATA1.bBlckSize], 1 ; Max block size in sectors
	191	jbe SHORT .BlockModeTransfersNotSupported
[158]	192	or BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
[150]	193	.BlockModeTransfersNotSupported:
	194	; Fall to .StoreDeviceSpecificParameters
[3]	195
	196	;--------------------------------------------------------------------
[150]	197	; .StoreDeviceSpecificParameters
[3]	198	; Parameters:
	199	; DS:DI: Ptr to Disk Parameter Table
	200	; ES:SI: Ptr to 512-byte ATA information read from the drive
[160]	201	; CS:BP: Ptr to IDEVARS for the controller
[3]	202	; Returns:
[99]	203	; Nothing
[3]	204	; Corrupts registers:
[150]	205	; AX, BX, CX, DX
[3]	206	;--------------------------------------------------------------------
[150]	207	.StoreDeviceSpecificParameters:
	208	call Device_FinalizeDPT
[258]	209
[262]	210	;----------------------------------------------------------------------
	211	; Update drive counts (hard and floppy)
[294]	212	;----------------------------------------------------------------------
	213
[258]	214	%ifdef MODULE_SERIAL_FLOPPY
	215	;
	216	; These two instructions serve two purposes:
	217	; 1. If the drive is a floppy drive (CF set), then we effectively increment the counter.
[294]	218	; 2. If this is a hard disk, and there have been any floppy drives previously added, then the hard disk is
[258]	219	; effectively discarded. This is more of a safety check then code that should ever normally be hit (see below).
[294]	220	; Since the floppy DPT's come after the hard disk DPT's, without expensive (code size) code to relocate a DPT,
[258]	221	; this was necessary. Now, this situation shouldn't happen in normal operation, for a couple of reasons:
[294]	222	; A. xtidecfg always puts configured serial ports at the end of the IDEVARS list
[258]	223	; B. the auto serial code is always executed last
	224	; C. the serial server always returns floppy drives last
	225	;
	226	adc byte [RAMVARS.xlateVars+XLATEVARS.bFlopCreateCnt], 0
[294]	227	jnz .AllDone
[258]	228	%else
	229	;
	230	; Even without floppy support enabled, we shouldn't try to mount a floppy image as a hard disk, which
[294]	231	; could lead to unpredictable results since no MBR will be present, etc. The server doesn't know that
[258]	232	; floppies are supported, so it is important to still fail here if a floppy is seen during the drive scan.
	233	;
	234	jc .AllDone
	235	%endif
	236
[150]	237	inc BYTE [RAMVARS.bDrvCnt] ; Increment drive count to RAMVARS
[294]	238
	239	.AllDone:
[162]	240	clc
[3]	241	ret
[258]	242
[324]	243
[422]	244	;--------------------------------------------------------------------
[473]	245	; CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI
	246	; Parameters:
	247	; DX: Autodetected port (for devices that support autodetection)
	248	; DS:DI: Ptr to Disk Parameter Table
	249	; CS:BP: Ptr to IDEVARS for the controller
	250	; Returns:
	251	; Nothing
	252	; Corrupts registers:
	253	; AX
	254	;--------------------------------------------------------------------
	255	CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI:
	256	mov [di+DPT.bIdevarsOffset], bp ; IDEVARS must start in first 256 bytes of ROM
	257
[493]	258	%ifdef MODULE_8BIT_IDE_ADVANCED
[473]	259	call DetectDrives_DoesIdevarsInCSBPbelongToXTCF
	260	jne SHORT .DeviceUsesPortSpecifiedInIDEVARS
	261	mov [di+DPT.wBasePort], dx
	262	ret
	263	.DeviceUsesPortSpecifiedInIDEVARS:
[493]	264	%endif ; MODULE_8BIT_IDE_ADVANCED
[473]	265
	266	mov ax, [cs:bp+IDEVARS.wBasePort]
	267	mov [di+DPT.wBasePort], ax
	268	ret

Note: See TracBrowser for help on using the repository browser.

Download in other formats: