source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/DetectDrives.asm @ 363

Last change on this file since 363 was 363, checked in by aitotat@…, 12 years ago

Changes to XTIDE Universal BIOS:

  • Added Advanced ATA Module (MODULE_ADVANCED_ATA) with native support for QDI Vision QD6500 and QD6580 VLB IDE Controllers.
  • Hopefully optimized IDE transfer functions for 8088 (replaced some memory accesses from WORD to BYTE).
  • XT build does not fit in 8k at the moment!!!
File size: 6.9 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for detecting drive for the BIOS.
3
4; Section containing code
5SECTION .text
6
7;--------------------------------------------------------------------
8; Detects all IDE hard disks to be controlled by this BIOS.
9;
10; DetectDrives_FromAllIDEControllers
11;   Parameters:
12;       DS:     RAMVARS segment
13;       ES:     BDA segment (zero)
14;   Returns:
15;       Nothing
16;   Corrupts registers:
17;       All (not segments)
18;--------------------------------------------------------------------
19DetectDrives_FromAllIDEControllers:
20    call    RamVars_GetIdeControllerCountToCX
21    mov     bp, ROMVARS.ideVars0            ; CS:BP now points to first IDEVARS
22
23.DriveDetectLoop:                           ; Loop through IDEVARS
24    push    cx
25
26    mov     cx, g_szDetectMaster
27    mov     bh, MASK_DRVNHEAD_SET                               ; Select Master drive
28    call    StartDetectionWithDriveSelectByteInBHandStringInCX  ; Detect and create DPT + BOOTNFO
29
30    mov     cx, g_szDetectSlave
31    mov     bh, MASK_DRVNHEAD_SET | FLG_DRVNHEAD_DRV
32    call    StartDetectionWithDriveSelectByteInBHandStringInCX
33
34    pop     cx
35
36    add     bp, BYTE IDEVARS_size           ; Point to next IDEVARS
37
38%ifdef MODULE_SERIAL
39    jcxz    .AddHardDisks                   ; Set to zero on .ideVarsSerialAuto iteration (if any)
40%endif
41
42    loop    .DriveDetectLoop
43
44%ifdef MODULE_SERIAL
45;----------------------------------------------------------------------
46;
47; if serial drive detected, do not scan (avoids duplicate drives and isn't needed - we already have a connection)
48;
49    call    FindDPT_ToDSDIforSerialDevice
50    jnc     .AddHardDisks
51
52    mov     bp, ROMVARS.ideVarsSerialAuto   ; Point to our special IDEVARS structure, just for serial scans
53
54    mov     al,[cs:ROMVARS.wFlags]          ; Configurator set to always scan?
55    or      al,[es:BDA.bKBFlgs1]            ; Or, did the user hold down the ALT key?
56    and     al,8                            ; 8 = alt key depressed, same as FLG_ROMVARS_SERIAL_ALWAYSDETECT
57    jnz     .DriveDetectLoop
58%endif
59
60.AddHardDisks:
61;----------------------------------------------------------------------
62;
63; Add in hard disks to BDA, finalize our Count and First variables
64;
65; Note that we perform the add to bHDCount and store bFirstDrv even if the count is zero.
66; This is done because we use the value of .bFirstDrv to know how many drives were in the system
67; at the time of boot, and to return that number on int13h/8h calls.  Because the count is zero,
68; FindDPT_ForDriveNumber will not find any drives that are ours.
69;
70    mov     cx, [RAMVARS.wDrvCntAndFlopCnt]     ; Our count of hard disks
71
72    mov     al, [es:BDA.bHDCount]
73    add     cl, al                      ; Add our drives to the system count
74    mov     [es:BDA.bHDCount], cl
75    or      al, 80h                     ; Or in hard disk flag
76    mov     [RAMVARS.bFirstDrv], al     ; Store first drive number
77
78.AddFloppies:
79%ifdef MODULE_SERIAL_FLOPPY
80;----------------------------------------------------------------------
81;
82; Add in any emulated serial floppy drives, finalize our packed Count and First variables
83;
84    dec     ch
85    mov     al, ch
86    js      .NoFloppies                     ; if no drives are present, we store 0ffh
87
88    call    FloppyDrive_GetCountFromBIOS_or_BDA
89
90    push    ax
91
92    add     al, ch                          ; Add our drives to existing drive count
93    cmp     al, 3                           ; For BDA, max out at 4 drives (ours is zero based)
94    jb      .MaxBDAFloppiesExceeded
95    mov     al, 3
96.MaxBDAFloppiesExceeded:
97    eROR_IM al, 2                           ; move to bits 6-7
98    inc     ax                              ; low order bit, indicating floppy drive exists
99
100    mov     ah, [es:BDA.wEquipment]         ; Load Equipment WORD low byte
101    and     ah, 03eh                        ; Mask off drive number and drives present bit
102    or      al, ah                          ; Or in new values
103    mov     [es:BDA.wEquipment], al         ; and store
104
105    mov     al, 1eh                         ; BDA pointer to Floppy DPT
106    mov     si, AH8h_FloppyDPT
107    call    Interrupts_InstallHandlerToVectorInALFromCSSI
108
109    pop     ax
110
111    shr     ch, 1                           ; number of drives, 1 or 2 only, to CF flag (clear=1, set=2)
112    rcl     al, 1                           ; starting drive number in upper 7 bits, number of drives in low bit
113.NoFloppies:
114    mov     [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst], al
115%endif
116
117    ret
118
119%ifndef CHECK_FOR_UNUSED_ENTRYPOINTS
120    %if FLG_ROMVARS_SERIAL_SCANDETECT != 8
121        %error "DetectDrives is currently coded to assume that FLG_ROMVARS_SERIAL_SCANDETECT is the same bit as the ALT key code in the BDA.  Changes in the code will be needed if these values are no longer the same."
122    %endif
123%endif
124
125
126;--------------------------------------------------------------------
127; StartDetectionWithDriveSelectByteInBHandStringInCX
128;   Parameters:
129;       BH:     Drive Select byte for Drive and Head Register
130;       CX:     Offset to "Master" or "Slave" string
131;       CS:BP:  Ptr to IDEVARS for the drive
132;       DS:     RAMVARS segment
133;       ES:     Zero (BDA segment)
134;   Returns:
135;       None
136;   Corrupts registers:
137;       AX, BX, CX, DX, SI, DI
138;--------------------------------------------------------------------
139StartDetectionWithDriveSelectByteInBHandStringInCX:
140    call    DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP
141    ; Fall to .ReadAtaInfoFromHardDisk
142
143;--------------------------------------------------------------------
144; .ReadAtaInfoFromHardDisk
145;   Parameters:
146;       BH:     Drive Select byte for Drive and Head Register
147;       CS:BP:  Ptr to IDEVARS for the drive
148;       DS:     RAMVARS segment
149;       ES:     Zero (BDA segment)
150;   Returns:
151;       CF:     Cleared if ATA-information read successfully
152;               Set if any error
153;   Corrupts registers:
154;       AX, BL, CX, DX, SI, DI
155;--------------------------------------------------------------------
156.ReadAtaInfoFromHardDisk:
157    mov     si, BOOTVARS.rgbAtaInfo     ; ES:SI now points to ATA info location
158    push    es
159    push    si
160    push    bx
161    call    Device_IdentifyToBufferInESSIwithDriveSelectByteInBH
162    pop     bx
163    pop     si
164    pop     es
165    jnc     SHORT CreateBiosTablesForHardDisk
166    ; Fall to .ReadAtapiInfoFromDrive
167
168.ReadAtapiInfoFromDrive:                ; Not yet implemented
169    ;call   ReadAtapiInfoFromDrive      ; Assume CD-ROM
170    ;jnc    SHORT _CreateBiosTablesForCDROM
171
172    ;jmp    short DetectDrives_DriveNotFound
173;;; fall-through instead of previous jmp instruction
174;--------------------------------------------------------------------
175; DetectDrives_DriveNotFound
176;   Parameters:
177;       Nothing
178;   Returns:
179;       CF:     Set (from BootMenuPrint_NullTerminatedStringFromCSSIandSetCF)
180;   Corrupts registers:
181;       AX, SI
182;--------------------------------------------------------------------
183DetectDrives_DriveNotFound:
184    mov     si, g_szNotFound
185    jmp     BootMenuPrint_NullTerminatedStringFromCSSIandSetCF
186
187
188;--------------------------------------------------------------------
189; CreateBiosTablesForHardDisk
190;   Parameters:
191;       BH:     Drive Select byte for Drive and Head Register
192;       CS:BP:  Ptr to IDEVARS for the drive
193;       ES:SI   Ptr to ATA information for the drive
194;       DS:     RAMVARS segment
195;       ES:     BDA/Bootnfo segment
196;   Returns:
197;       Nothing
198;   Corrupts registers:
199;       AX, BX, CX, DX, SI, DI
200;--------------------------------------------------------------------
201CreateBiosTablesForHardDisk:
202    call    CreateDPT_FromAtaInformation
203    jc      SHORT DetectDrives_DriveNotFound
204    call    BootMenuInfo_CreateForHardDisk
205    jmp     short DetectPrint_DriveNameFromBootnfoInESBX
Note: See TracBrowser for help on using the repository browser.