1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Int 13h function AH=48h, Get Extended Drive Parameters. |
---|
3 | |
---|
4 | ; Section containing code |
---|
5 | SECTION .text |
---|
6 | |
---|
7 | ;-------------------------------------------------------------------- |
---|
8 | ; Int 13h function AH=48h, Get Extended Drive Parameters. |
---|
9 | ; |
---|
10 | ; AH48h_GetExtendedDriveParameters |
---|
11 | ; Parameters: |
---|
12 | ; SI: Same as in INTPACK |
---|
13 | ; DL: Translated Drive number |
---|
14 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
15 | ; SS:BP: Ptr to IDEPACK |
---|
16 | ; Parameters on INTPACK: |
---|
17 | ; DS:SI: Ptr to Extended Drive Information Table to fill |
---|
18 | ; Returns with INTPACK: |
---|
19 | ; AH: Int 13h return status |
---|
20 | ; DS:SI: Ptr to Extended Drive Information Table |
---|
21 | ; CF: 0 if succesfull, 1 if error |
---|
22 | ;-------------------------------------------------------------------- |
---|
23 | AH48h_HandlerForGetExtendedDriveParameters: |
---|
24 | call AccessDPT_GetPointerToDRVPARAMStoCSBX |
---|
25 | push bx |
---|
26 | call AccessDPT_GetLbaSectorCountToBXDXAX |
---|
27 | pop di ; CS:DI now points to DRVPARAMS |
---|
28 | |
---|
29 | ; Point DS:SI to Extended Drive Information Table to fill |
---|
30 | mov ds, [bp+IDEPACK.intpack+INTPACK.ds] |
---|
31 | mov cx, MINIMUM_EDRIVEINFO_SIZE |
---|
32 | cmp [si+EDRIVE_INFO.wSize], cx |
---|
33 | jb SHORT Prepare_ReturnFromInt13hWithInvalidFunctionError |
---|
34 | je SHORT .SkipEddConfigurationParameters |
---|
35 | |
---|
36 | ; We do not support EDD Configuration Parameters so set to FFFF:FFFFh |
---|
37 | mov cx, -1 ; FFFFh |
---|
38 | mov [si+EDRIVE_INFO.fpEDDparams], cx |
---|
39 | mov [si+EDRIVE_INFO.fpEDDparams+2], cx |
---|
40 | mov cx, EDRIVE_INFO_size |
---|
41 | |
---|
42 | ; Fill Extended Drive Information Table in DS:SI |
---|
43 | .SkipEddConfigurationParameters: |
---|
44 | mov [si+EDRIVE_INFO.wSize], cx |
---|
45 | mov WORD [si+EDRIVE_INFO.wFlags], FLG_DMA_BOUNDARY_ERRORS_HANDLED_BY_BIOS |
---|
46 | |
---|
47 | push ds ; Move CS to DS to avoid segment overrides |
---|
48 | push cs |
---|
49 | pop ds |
---|
50 | |
---|
51 | ; Limit LBA if necessary |
---|
52 | test BYTE [di+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERLBA |
---|
53 | jz SHORT .StoreTotalSectorsFromBXDXAX |
---|
54 | test bx, bx |
---|
55 | jnz SHORT .LimitTotalSectors |
---|
56 | cmp dx, [di+DRVPARAMS.dwMaximumLBA+2] |
---|
57 | jb SHORT .StoreTotalSectorsFromBXDXAX ; Real size less than max |
---|
58 | ja SHORT .LimitTotalSectors |
---|
59 | cmp ax, [di+DRVPARAMS.dwMaximumLBA] |
---|
60 | jbe SHORT .StoreTotalSectorsFromBXDXAX ; Real size less than max |
---|
61 | |
---|
62 | .LimitTotalSectors: |
---|
63 | xor bx, bx |
---|
64 | mov ax, [di+DRVPARAMS.dwMaximumLBA] |
---|
65 | mov dx, [di+DRVPARAMS.dwMaximumLBA+2] |
---|
66 | |
---|
67 | .StoreTotalSectorsFromBXDXAX: |
---|
68 | pop ds ; Restore DS from the change above |
---|
69 | mov [si+EDRIVE_INFO.qwTotalSectors], ax |
---|
70 | xor ax, ax ; Return with success |
---|
71 | mov [si+EDRIVE_INFO.qwTotalSectors+2], dx |
---|
72 | mov [si+EDRIVE_INFO.qwTotalSectors+4], bx |
---|
73 | mov [si+EDRIVE_INFO.qwTotalSectors+6], ax ; Always zero |
---|
74 | mov WORD [si+EDRIVE_INFO.wSectorSize], 512 |
---|
75 | |
---|
76 | .ReturnWithError: |
---|
77 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|