source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AHDh_HReset.asm @ 376

Last change on this file since 376 was 376, checked in by gregli@…, 12 years ago

WIDE checkin... Added copyright and license information to sorce files, as per the GPL instructions for usage.

File size: 4.5 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=Dh, Reset Hard Disk (Alternate reset).
3
4;
5; XTIDE Universal BIOS and Associated Tools 
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12; 
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html               
18;               
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Int 13h function AH=Dh, Reset Hard Disk (Alternate reset).
25;
26; AHDh_HandlerForResetHardDisk
27;   Parameters:
28;       DL:     Translated Drive number
29;       DS:DI:  Ptr to DPT (in RAMVARS segment)
30;       SS:BP:  Ptr to IDEPACK
31;   Returns with INTPACK:
32;       AH:     Int 13h return status
33;       CF:     0 if successful, 1 if error
34;--------------------------------------------------------------------
35AHDh_HandlerForResetHardDisk:
36%ifndef USE_186
37    call    AHDh_ResetDrive
38    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
39%else
40    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
41    ; Fall to AHDh_ResetDrive
42%endif
43
44
45;--------------------------------------------------------------------
46; Resets hard disk.
47;
48; AHDh_ResetDrive
49;   Parameters:
50;       DS:DI:  Ptr to DPT
51;       SS:BP:  Ptr to IDEPACK
52;   Returns:
53;       AH:     Int 13h return status
54;       CF:     0 if successful, 1 if error
55;   Corrupts registers:
56;       AL, SI
57;--------------------------------------------------------------------
58AHDh_ResetDrive:
59    push    dx
60    push    cx
61    push    bx
62    push    di
63
64    call    Interrupts_UnmaskInterruptControllerForDriveInDSDI
65    call    Device_ResetMasterAndSlaveController
66    ;jc     SHORT .ReturnError                  ; CF would be set if slave drive present without master
67                                                ; (error register has special values after reset)
68
69    ; Initialize Master and Slave drives
70    eMOVZX  ax, [di+DPT.bIdevarsOffset]         ; (AL) pointer to controller we are looking to reset
71                                                ; (AH) initialize error code, assume success
72
73    mov     si, IterateAndResetDrives           ; Callback function for FindDPT_IterateAllDPTs
74    call    FindDPT_IterateAllDPTs
75
76    shr     ah, 1                               ; Move error code and CF into proper position
77
78    pop     di
79    pop     bx
80    pop     cx
81    pop     dx
82    ret
83
84;--------------------------------------------------------------------
85; IterateAndResetDrives: Iteration routine for use with IterateAllDPTs.
86;
87; When a drive on the controller is found, it is reset, and the error code
88; merged into overall error code for this controller.  Master will be reset
89; first.  Note that the iteration will go until the end of the DPT list.
90;
91;   Parameters:
92;       AL:     Offset to IDEVARS for drives to initialize
93;       AH:     Error status from previous initialization
94;       DS:DI:  Ptr to DPT to examine
95;   Returns:
96;       AH:     Error status from initialization
97;       CF:     Set to iterate all DPTs
98;   Corrupts registers:
99;       AL, BX, DX
100;--------------------------------------------------------------------
101IterateAndResetDrives:
102    cmp     al, [di+DPT.bIdevarsOffset]         ; The right controller?
103    jne     .Done
104    push    cx
105    push    ax
106    call    AH9h_InitializeDriveForUse          ; Reset Master and Slave (Master will come first in DPT list)
107
108%ifdef MODULE_ADVANCED_ATA
109    jc      SHORT .SkipControllerInitSinceError
110    ; Here we initialize the more advanced controllers (VLB and PCI) to get better performance for systems with 32-bit bus.
111    ; This step is optional since the controllers use slowest possible settings by default if they are not initialized.
112
113    pop     ax
114    push    ax
115    cmp     al, [di+LARGEST_DPT_SIZE+DPT.bIdevarsOffset]    ; We check if next DPT is for the same IDE controller.
116    je      SHORT .SkipInitializationUntilNextDrive         ; If it is, we skip the initialization.
117    call    AdvAtaInit_InitializeControllerForDPTinDSDI     ; Done after drive init so drives are first set to advanced PIO mode, then the controller
118.SkipInitializationUntilNextDrive:
119.SkipControllerInitSinceError:
120%endif  ; MODULE_ADVANCED_ATA
121
122    pop     ax
123    pop     cx
124    jnc     .Done
125    or      ah, (RET_HD_RESETFAIL << 1) | 1     ; OR in Reset Failed error code and CF, will SHR into position later
126.Done:
127    stc                                         ; From IterateAllDPTs perspective, the DPT is never found (continue iteration)
128    ret
129
Note: See TracBrowser for help on using the repository browser.