1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : IDE Device Command functions. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; IdeCommand_ResetMasterAndSlaveController |
---|
25 | ; Parameters: |
---|
26 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
27 | ; Returns: |
---|
28 | ; AH: INT 13h Error Code |
---|
29 | ; CF: Cleared if success, Set if error |
---|
30 | ; Corrupts registers: |
---|
31 | ; AL, BX, CX, DX |
---|
32 | ;-------------------------------------------------------------------- |
---|
33 | IdeCommand_ResetMasterAndSlaveController: |
---|
34 | ; HSR0: Set_SRST |
---|
35 | call AccessDPT_GetDeviceControlByteToAL |
---|
36 | or al, FLG_DEVCONTROL_SRST | FLG_DEVCONTROL_nIEN ; Set Reset bit |
---|
37 | OUTPUT_AL_TO_IDE_CONTROL_BLOCK_REGISTER DEVICE_CONTROL_REGISTER_out |
---|
38 | mov ax, HSR0_RESET_WAIT_US |
---|
39 | call Timer_DelayMicrosecondsFromAX |
---|
40 | |
---|
41 | ; HSR1: Clear_wait |
---|
42 | call AccessDPT_GetDeviceControlByteToAL |
---|
43 | or al, FLG_DEVCONTROL_nIEN |
---|
44 | and al, ~FLG_DEVCONTROL_SRST ; Clear reset bit |
---|
45 | OUTPUT_AL_TO_IDE_CONTROL_BLOCK_REGISTER DEVICE_CONTROL_REGISTER_out |
---|
46 | mov ax, HSR1_RESET_WAIT_US |
---|
47 | call Timer_DelayMicrosecondsFromAX |
---|
48 | |
---|
49 | ; HSR2: Check_status |
---|
50 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_MOTOR_STARTUP, FLG_STATUS_BSY) |
---|
51 | jmp IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
52 | |
---|
53 | |
---|
54 | ;-------------------------------------------------------------------- |
---|
55 | ; IdeCommand_IdentifyDeviceToBufferInESSIwithDriveSelectByteInBH |
---|
56 | ; Parameters: |
---|
57 | ; BH: Drive Select byte for Drive and Head Select Register |
---|
58 | ; DS: Segment to RAMVARS |
---|
59 | ; ES:SI: Ptr to buffer to receive 512-byte IDE Information |
---|
60 | ; CS:BP: Ptr to IDEVARS |
---|
61 | ; Returns: |
---|
62 | ; AH: INT 13h Error Code |
---|
63 | ; CF: Cleared if success, Set if error |
---|
64 | ; Corrupts registers: |
---|
65 | ; AL, BL, CX, DX, SI, DI, ES |
---|
66 | ;-------------------------------------------------------------------- |
---|
67 | IdeCommand_IdentifyDeviceToBufferInESSIwithDriveSelectByteInBH: |
---|
68 | ; Create fake DPT to be able to use Device.asm functions |
---|
69 | call FindDPT_ForNewDriveToDSDI |
---|
70 | eMOVZX ax, bh |
---|
71 | mov [di+DPT.wFlags], ax |
---|
72 | mov [di+DPT.bIdevarsOffset], bp |
---|
73 | mov BYTE [di+DPT_ATA.bBlockSize], 1 ; Block = 1 sector |
---|
74 | call IdeDPT_StoreDeviceTypeFromIdevarsInCSBPtoDPTinDSDI |
---|
75 | |
---|
76 | ; Wait until drive motors have reached max speed |
---|
77 | cmp bp, BYTE ROMVARS.ideVars0 |
---|
78 | jne SHORT .SkipLongWaitSinceDriveIsNotPrimaryMaster |
---|
79 | test bh, FLG_DRVNHEAD_DRV |
---|
80 | jnz SHORT .SkipLongWaitSinceDriveIsNotPrimaryMaster |
---|
81 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_MOTOR_STARTUP, FLG_STATUS_BSY) |
---|
82 | call IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
83 | .SkipLongWaitSinceDriveIsNotPrimaryMaster: |
---|
84 | |
---|
85 | ; Create IDEPACK without INTPACK |
---|
86 | push bp |
---|
87 | call Idepack_FakeToSSBP |
---|
88 | |
---|
89 | ; Prepare to output Identify Device command |
---|
90 | mov dl, 1 ; Sector count (required by IdeTransfer.asm) |
---|
91 | mov al, COMMAND_IDENTIFY_DEVICE |
---|
92 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_IDENTIFY_DEVICE, FLG_STATUS_DRQ) |
---|
93 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL |
---|
94 | |
---|
95 | ; Clean stack and return |
---|
96 | lea sp, [bp+EXTRA_BYTES_FOR_INTPACK] ; This assumes BP hasn't changed between Idepack_FakeToSSBP and here |
---|
97 | pop bp |
---|
98 | ret |
---|
99 | |
---|
100 | |
---|
101 | ;-------------------------------------------------------------------- |
---|
102 | ; IdeCommand_OutputWithParameters |
---|
103 | ; Parameters: |
---|
104 | ; BH: System timer ticks for timeout |
---|
105 | ; BL: IDE Status Register bit to poll after command |
---|
106 | ; ES:SI: Ptr to buffer (for data transfer commands) |
---|
107 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
108 | ; SS:BP: Ptr to IDEPACK |
---|
109 | ; Returns: |
---|
110 | ; AH: INT 13h Error Code |
---|
111 | ; CX: Number of successfully transferred sectors (for transfer commands) |
---|
112 | ; CF: Cleared if success, Set if error |
---|
113 | ; Corrupts registers: |
---|
114 | ; AL, BX, (CX), DX, (ES:SI for data transfer commands) |
---|
115 | ;-------------------------------------------------------------------- |
---|
116 | ALIGN JUMP_ALIGN |
---|
117 | IdeCommand_OutputWithParameters: |
---|
118 | push bx ; Store status register bits to poll |
---|
119 | |
---|
120 | ; Select Master or Slave drive and output head number or LBA28 top bits |
---|
121 | call IdeCommand_SelectDrive |
---|
122 | jc SHORT .DriveNotReady |
---|
123 | |
---|
124 | ; Output Device Control Byte to enable or disable interrupts |
---|
125 | mov al, [bp+IDEPACK.bDeviceControl] |
---|
126 | %ifdef MODULE_IRQ |
---|
127 | test al, FLG_DEVCONTROL_nIEN ; Interrupts disabled? |
---|
128 | jnz SHORT .DoNotSetInterruptInServiceFlag |
---|
129 | |
---|
130 | ; Clear Task Flag and set Interrupt In-Service Flag |
---|
131 | or BYTE [di+DPT.bFlagsHigh], FLGH_DPT_INTERRUPT_IN_SERVICE |
---|
132 | push ds |
---|
133 | LOAD_BDA_SEGMENT_TO ds, dx, ! ; Also zero DX |
---|
134 | mov [BDA.bHDTaskFlg], dl |
---|
135 | pop ds |
---|
136 | .DoNotSetInterruptInServiceFlag: |
---|
137 | %endif |
---|
138 | OUTPUT_AL_TO_IDE_CONTROL_BLOCK_REGISTER DEVICE_CONTROL_REGISTER_out |
---|
139 | |
---|
140 | ; Output Feature Number |
---|
141 | mov al, [bp+IDEPACK.bFeatures] |
---|
142 | OUTPUT_AL_TO_IDE_REGISTER FEATURES_REGISTER_out |
---|
143 | |
---|
144 | ; Output Sector Address High (only used by LBA48) |
---|
145 | %ifdef MODULE_EBIOS |
---|
146 | eMOVZX ax, [bp+IDEPACK.bLbaLowExt] ; Zero sector count |
---|
147 | mov cx, [bp+IDEPACK.wLbaMiddleAndHighExt] |
---|
148 | call OutputSectorCountAndAddress |
---|
149 | %endif |
---|
150 | |
---|
151 | ; Output Sector Address Low |
---|
152 | mov ax, [bp+IDEPACK.wSectorCountAndLbaLow] |
---|
153 | mov cx, [bp+IDEPACK.wLbaMiddleAndHigh] |
---|
154 | call OutputSectorCountAndAddress |
---|
155 | |
---|
156 | ; Output command |
---|
157 | mov al, [bp+IDEPACK.bCommand] |
---|
158 | OUTPUT_AL_TO_IDE_REGISTER COMMAND_REGISTER_out |
---|
159 | |
---|
160 | ; Wait until command completed |
---|
161 | pop bx ; Pop status and timeout for polling |
---|
162 | cmp bl, FLG_STATUS_DRQ ; Data transfer started? |
---|
163 | jne SHORT .WaitUntilNonTransferCommandCompletes |
---|
164 | %ifdef MODULE_JRIDE |
---|
165 | cmp BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_JRIDE_ISA |
---|
166 | je SHORT JrIdeTransfer_StartWithCommandInAL |
---|
167 | %endif |
---|
168 | jmp IdeTransfer_StartWithCommandInAL |
---|
169 | |
---|
170 | .WaitUntilNonTransferCommandCompletes: |
---|
171 | %ifdef MODULE_IRQ |
---|
172 | test BYTE [bp+IDEPACK.bDeviceControl], FLG_DEVCONTROL_nIEN |
---|
173 | jz SHORT .PollStatusFlagInsteadOfWaitIrq |
---|
174 | jmp IdeWait_IRQorStatusFlagInBLwithTimeoutInBH |
---|
175 | .PollStatusFlagInsteadOfWaitIrq: |
---|
176 | %endif |
---|
177 | jmp IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
178 | |
---|
179 | .DriveNotReady: |
---|
180 | pop bx ; Clean stack |
---|
181 | ret |
---|
182 | |
---|
183 | |
---|
184 | ;-------------------------------------------------------------------- |
---|
185 | ; IdeCommand_SelectDrive |
---|
186 | ; Parameters: |
---|
187 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
188 | ; SS:BP: Ptr to IDEPACK |
---|
189 | ; Returns: |
---|
190 | ; AH: INT 13h Error Code |
---|
191 | ; CF: Cleared if success, Set if error |
---|
192 | ; Corrupts registers: |
---|
193 | ; AL, BX, CX, DX |
---|
194 | ;-------------------------------------------------------------------- |
---|
195 | ALIGN JUMP_ALIGN |
---|
196 | IdeCommand_SelectDrive: |
---|
197 | ; Wait until neither Master or Slave Drive is busy |
---|
198 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY) |
---|
199 | cmp BYTE [bp+IDEPACK.bCommand], COMMAND_IDENTIFY_DEVICE |
---|
200 | eCMOVE bh, TIMEOUT_IDENTIFY_DEVICE |
---|
201 | call IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
202 | |
---|
203 | ; Select Master or Slave Drive |
---|
204 | mov al, [bp+IDEPACK.bDrvAndHead] |
---|
205 | OUTPUT_AL_TO_IDE_REGISTER DRIVE_AND_HEAD_SELECT_REGISTER |
---|
206 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRDY, FLG_STATUS_DRDY) |
---|
207 | cmp BYTE [bp+IDEPACK.bCommand], COMMAND_IDENTIFY_DEVICE |
---|
208 | eCMOVE bh, TIMEOUT_IDENTIFY_DEVICE |
---|
209 | call IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
210 | |
---|
211 | ; Ignore errors from IDE Error Register (set by previous command) |
---|
212 | cmp ah, RET_HD_TIMEOUT |
---|
213 | je SHORT .FailedToSelectDrive |
---|
214 | xor ax, ax ; Always success unless timeout |
---|
215 | ret |
---|
216 | .FailedToSelectDrive: |
---|
217 | stc |
---|
218 | ret |
---|
219 | |
---|
220 | |
---|
221 | ;-------------------------------------------------------------------- |
---|
222 | ; OutputSectorCountAndAddress |
---|
223 | ; Parameters: |
---|
224 | ; AH: LBA low bits (Sector Number) |
---|
225 | ; AL: Sector Count |
---|
226 | ; CL: LBA middle bits (Cylinder Number low) |
---|
227 | ; CH: LBA high bits (Cylinder Number high) |
---|
228 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
229 | ; Returns: |
---|
230 | ; Nothing |
---|
231 | ; Corrupts registers: |
---|
232 | ; AL, BX, DX |
---|
233 | ;-------------------------------------------------------------------- |
---|
234 | ALIGN JUMP_ALIGN |
---|
235 | OutputSectorCountAndAddress: |
---|
236 | OUTPUT_AL_TO_IDE_REGISTER SECTOR_COUNT_REGISTER |
---|
237 | |
---|
238 | mov al, ah |
---|
239 | OUTPUT_AL_TO_IDE_REGISTER LBA_LOW_REGISTER |
---|
240 | |
---|
241 | mov al, cl |
---|
242 | OUTPUT_AL_TO_IDE_REGISTER LBA_MIDDLE_REGISTER |
---|
243 | |
---|
244 | mov al, ch |
---|
245 | JUMP_TO_OUTPUT_AL_TO_IDE_REGISTER LBA_HIGH_REGISTER |
---|