1 | ; Project name : Assembly Library |
---|
2 | ; Description : Functions for accessing drives. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; Drive_GetNumberOfAvailableDrivesToAX |
---|
25 | ; Parameters: |
---|
26 | ; Nothing |
---|
27 | ; Returns: |
---|
28 | ; AX: Number of available drives |
---|
29 | ; Corrupts registers: |
---|
30 | ; Nothing |
---|
31 | ;-------------------------------------------------------------------- |
---|
32 | ALIGN JUMP_ALIGN |
---|
33 | Drive_GetNumberOfAvailableDrivesToAX: |
---|
34 | push dx |
---|
35 | push cx |
---|
36 | |
---|
37 | call Drive_GetFlagsForAvailableDrivesToDXAX |
---|
38 | call Bit_GetSetCountToCXfromDXAX |
---|
39 | xchg ax, cx |
---|
40 | |
---|
41 | pop cx |
---|
42 | pop dx |
---|
43 | ret |
---|
44 | |
---|
45 | |
---|
46 | ;-------------------------------------------------------------------- |
---|
47 | ; Drive_GetFlagsForAvailableDrivesToDXAX |
---|
48 | ; Parameters: |
---|
49 | ; Nothing |
---|
50 | ; Returns: |
---|
51 | ; DX:AX: Flags containing valid drives (bit 0 = drive A, bit 1 = drive B ...) |
---|
52 | ; Corrupts registers: |
---|
53 | ; Nothing |
---|
54 | ;-------------------------------------------------------------------- |
---|
55 | ALIGN JUMP_ALIGN |
---|
56 | Drive_GetFlagsForAvailableDrivesToDXAX: |
---|
57 | push cx |
---|
58 | push bx |
---|
59 | mov dx, DosCritical_HandlerToIgnoreAllErrors |
---|
60 | call DosCritical_InstallNewHandlerFromCSDX |
---|
61 | |
---|
62 | call .GetNumberOfPotentiallyValidDriveLettersToCX |
---|
63 | xor bx, bx |
---|
64 | xor ax, ax ; Temporary use BX:AX for flags |
---|
65 | cwd ; Start from drive 0 |
---|
66 | call .CheckDriveValidityUntilCXisZero |
---|
67 | mov dx, bx ; Flags now in DX:AX |
---|
68 | |
---|
69 | call DosCritical_RestoreDosHandler |
---|
70 | pop bx |
---|
71 | pop cx |
---|
72 | ret |
---|
73 | |
---|
74 | ;-------------------------------------------------------------------- |
---|
75 | ; .GetNumberOfPotentiallyValidDriveLettersToCX |
---|
76 | ; Parameters: |
---|
77 | ; Nothing |
---|
78 | ; Returns: |
---|
79 | ; CX: Number of potentially valid drive letters available |
---|
80 | ; Corrupts registers: |
---|
81 | ; AX, DX |
---|
82 | ;-------------------------------------------------------------------- |
---|
83 | ALIGN JUMP_ALIGN |
---|
84 | .GetNumberOfPotentiallyValidDriveLettersToCX: |
---|
85 | call Drive_GetDefaultToAL |
---|
86 | xchg dx, ax ; Default drive to DL |
---|
87 | call Drive_SetDefaultFromDL |
---|
88 | cmp al, 32 ; Number of potentially valid drive letters available |
---|
89 | jb SHORT .Below32 |
---|
90 | mov al, 32 |
---|
91 | .Below32: |
---|
92 | cbw |
---|
93 | xchg cx, ax |
---|
94 | ret |
---|
95 | |
---|
96 | ;-------------------------------------------------------------------- |
---|
97 | ; .CheckDriveValidityUntilCXisZero |
---|
98 | ; Parameters: |
---|
99 | ; CX: Number of potentially valid drive letters left |
---|
100 | ; DL: Drive number (00h=A:, 01h=B: ...) |
---|
101 | ; BX:AX: Flags for drive numbers |
---|
102 | ; Returns: |
---|
103 | ; BX:AX: Flags for valid drive numbers |
---|
104 | ; Corrupts registers: |
---|
105 | ; CX, DX |
---|
106 | ;-------------------------------------------------------------------- |
---|
107 | ALIGN JUMP_ALIGN |
---|
108 | .CheckDriveValidityUntilCXisZero: |
---|
109 | call .IsValidDriveNumberInDL |
---|
110 | jnz SHORT .PrepareToCheckNextDrive |
---|
111 | call .SetFlagToBXAXfromDriveInDL |
---|
112 | ALIGN JUMP_ALIGN |
---|
113 | .PrepareToCheckNextDrive: |
---|
114 | inc dx |
---|
115 | loop .CheckDriveValidityUntilCXisZero |
---|
116 | ret |
---|
117 | |
---|
118 | ;-------------------------------------------------------------------- |
---|
119 | ; .IsValidDriveNumberInDL |
---|
120 | ; Parameters: |
---|
121 | ; DL: Drive number (00h=A:, 01h=B: ...) |
---|
122 | ; Returns: |
---|
123 | ; ZF: Set if drive number is valid |
---|
124 | ; Cleared if drive number is invalid |
---|
125 | ; Corrupts registers: |
---|
126 | ; Nothing |
---|
127 | ;-------------------------------------------------------------------- |
---|
128 | ALIGN JUMP_ALIGN |
---|
129 | .IsValidDriveNumberInDL: |
---|
130 | push ds |
---|
131 | push bx |
---|
132 | push ax |
---|
133 | |
---|
134 | inc dx ; Default drive is 00h and first drive is 01h |
---|
135 | mov ax, CHECK_IF_BLOCK_DEVICE_REMOTE ; Needs DOS 3.1+ |
---|
136 | mov bx, dx |
---|
137 | push dx |
---|
138 | int DOS_INTERRUPT_21h |
---|
139 | pop dx |
---|
140 | jnc SHORT .DriveIsValid |
---|
141 | cmp ax, ERR_DOS_INVALID_DRIVE |
---|
142 | je SHORT .DriveIsNotValid |
---|
143 | ; Fall back to old method if ERR_DOS_FUNCTION_NUMBER_INVALID |
---|
144 | |
---|
145 | mov ah, GET_DOS_DRIVE_PARAMETER_BLOCK_FOR_SPECIFIC_DRIVE |
---|
146 | int DOS_INTERRUPT_21h |
---|
147 | .DriveIsValid: |
---|
148 | .DriveIsNotValid: |
---|
149 | dec dx |
---|
150 | test al, al |
---|
151 | |
---|
152 | pop ax |
---|
153 | pop bx |
---|
154 | pop ds |
---|
155 | ret |
---|
156 | |
---|
157 | ;-------------------------------------------------------------------- |
---|
158 | ; .SetFlagToBXAXfromDriveInDL |
---|
159 | ; Parameters: |
---|
160 | ; DL: Drive number (0...31) |
---|
161 | ; BX:AX: Flags containing drive numbers |
---|
162 | ; Returns: |
---|
163 | ; BX:AX: Flags with wanted drive bit set |
---|
164 | ; Corrupts registers: |
---|
165 | ; Nothing |
---|
166 | ;-------------------------------------------------------------------- |
---|
167 | ALIGN JUMP_ALIGN |
---|
168 | .SetFlagToBXAXfromDriveInDL: |
---|
169 | push cx |
---|
170 | |
---|
171 | mov cl, dl |
---|
172 | xchg dx, bx |
---|
173 | call Bit_SetToDXAXfromIndexInCL |
---|
174 | xchg bx, dx |
---|
175 | |
---|
176 | pop cx |
---|
177 | ret |
---|
178 | |
---|
179 | |
---|
180 | ;-------------------------------------------------------------------- |
---|
181 | ; Drive_GetDefaultToAL |
---|
182 | ; Parameters: |
---|
183 | ; Nothing |
---|
184 | ; Returns: |
---|
185 | ; AL: Current default drive (00h=A:, 01h=B: ...) |
---|
186 | ; Corrupts registers: |
---|
187 | ; AH |
---|
188 | ;-------------------------------------------------------------------- |
---|
189 | ALIGN JUMP_ALIGN |
---|
190 | Drive_GetDefaultToAL: |
---|
191 | mov ah, GET_CURRENT_DEFAULT_DRIVE |
---|
192 | SKIP2B f ; cmp ax, <next instruction> |
---|
193 | ; Fall to Drive_SetDefaultFromDL |
---|
194 | |
---|
195 | |
---|
196 | ;-------------------------------------------------------------------- |
---|
197 | ; Drive_SetDefaultFromDL |
---|
198 | ; Parameters: |
---|
199 | ; DL: New default drive (00h=A:, 01h=B: ...) |
---|
200 | ; Returns: |
---|
201 | ; AL: Number of potentially valid drive letters available |
---|
202 | ; Corrupts registers: |
---|
203 | ; AH |
---|
204 | ;-------------------------------------------------------------------- |
---|
205 | Drive_SetDefaultFromDL: |
---|
206 | mov ah, SELECT_DEFAULT_DRIVE |
---|
207 | int DOS_INTERRUPT_21h |
---|
208 | ret |
---|